Redeye Script

01 · Sintaxe

Sintaxe básica

Scripts são executados em um sandbox isolado a cada invocação. Variáveis declaradas dentro do script só vivem durante aquela execução; pra persistir use storage.

var nome = "Redeye"     // mutável
const pi = 3.14         // constante

nome = "Outro"          // ok
pi = 3                  // erro em runtime

if user.name == "Victor" {
    reply "Olá, criador!"
} else if user.isBot {
    reply "Você é um bot."
} else {
    reply "Olá, {user.name}!"
}

fun dobro(n) {
    return n * 2
}

reply "O dobro de 5 é {dobro(5)}"

var target = args[0] ?? user
reply "Alvo: {target.name}"

reply "Olá, mundo"          // bare-call
reply("Olá, mundo")         // chamada explícita - equivalente

02 · Tipos

Tipos primitivos

Seis tipos exposto à linguagem. typeof() também pode retornar "function" para funções definidas pelo usuário e "proxy" para handlers nativos como storage.

var nome = "Victor"
reply "Olá, {nome}!"        // Olá, Victor!
reply "1 + 2 = {1 + 2}"     // 1 + 2 = 3

var perfil = {
    nome: "Victor",
    nivel: 10,
    vip: true
}

reply "{perfil.nome} é nível {perfil.nivel}"
perfil["nivel"] = 11    // index assignment também funciona

03 · Operadores

Operadores

Atenção operadores & e | sozinhos são erro de lexer. Use sempre && / ||.

04 · Strings

Métodos de string

Acessíveis via dot/call em qualquer valor string.

Limite strings são limitadas a 1 MB de tamanho durante a execução.

05 · Listas

Métodos de lista

var nums = list(10, 20, 30)
reply nums[0]               // 10
nums[1] = 99                // index assignment
reply nums.length           // 3

Limite listas são limitadas a 10.000 elementos.

06 · Built-ins

Funções built-in

07 · Contexto

Objetos de contexto

Esses objetos estão disponíveis automaticamente em qualquer script invocado por comando.

08 · Args

Argumentos do comando

Os argumentos são acessados via args, uma lista posicional. Tipagem é definida nas opções do script (no painel) - user, number, string... - e o bot já entrega o valor já resolvido.

// Comando configurado com 2 opções: target (user) e amount (number)
var alvo = args[0] ?? user      // padrão: quem executou
var qtd = args[1] ?? 1

reply "{alvo.asMention} recebeu {qtd} pontos!"

09 · Storage

Storage persistente

Key-value persistente compartilhado entre todos os scripts do mesmo servidor. Aceita string, number, boolean, list e object como valor.

var dados = storage.get(user.id)

if dados == null {
    storage.set(user.id, { pontos: 0, nivel: 1 })
    reply "Conta criada!"
} else {
    dados.pontos = dados.pontos + 1
    storage.set(user.id, dados)
    reply "Você tem {dados.pontos} pontos!"
}

Limites plano free: até 500 chaves por servidor; cada valor pode ter no máximo 4 KB serializado. Tiers Premium aumentam ambos.

10 · Secrets

Secrets (chaves de API)

Valores criptografados configurados no painel e injetados na execução. Apenas leitura - scripts não podem sobrescrever.

var apiKey = secrets.get("MINHA_API_KEY")
var res = fetch("https://api.exemplo.com/dados?key={apiKey}")
reply "Resposta: {res.status}"

11 · Embeds

Embeds

Mensagens ricas com layout do Discord. O bloco embed { ... } é uma builder call - pode ser passado direto pra reply.

reply embed {
    title "Título do embed"
    description "Uma descrição legal"
    color "#dc2626"
    thumbnail user.avatar

    field("Campo 1", "Valor 1", true)
    field("Campo 2", "Valor 2", true)

    footer "Redeye Bot"
    footerIcon user.avatar
}

12 · HTTP

HTTP (fetch)

Requisições GET para APIs externas. Apenas HTTPS. JSON é parseado automaticamente; resposta não-JSON volta como string.

var res = fetch("https://api.exemplo.com/dados")

// res já vem parseado se for JSON
reply "Resultado: {res.campo}"

13 · Cargos

Manipulação de cargos

Adicionar e remover cargos é uma chamada à API do Discord, contabilizada num contador compartilhado de 10 chamadas por execução.

var role = guild.getRoleById("123456789")
if role != null && !user.hasRole(role.name) {
    guild.addRoleToMember(user.id, role.id)
    reply "{role.asMention} adicionado a {user.asMention}"
}

Permissões o bot precisa ter cargo acima do alvo e a permissão Manage Roles pra que a operação funcione.

14 · Cronjobs

Cronjobs (premium)

Scripts que rodam automaticamente em intervalos definidos. Disponível em servidores com tier Macula (10), Retina (50) ou Sclera (200 cronjobs por servidor).

Aceita dois formatos de schedule:

Sandbox cronjobs não têm user, channel nem args disponíveis. Pra postar mensagens, você configura um canal-alvo ou usa um webhook.

15 · Limites

Limites de execução

Aplicados por execução pra manter o sandbox justo. Atingir qualquer limite aborta o script com erro.

16 · Exemplos

Exemplos completos

if random(2) == 0 {
    reply "Cara!"
} else {
    reply "Coroa!"
}

var target = args[0] ?? user
var dados = storage.get(target.id) ?? { count: 0 }

dados.count = dados.count + 1
storage.set(target.id, dados)

reply "{target.name} agora tem {dados.count} pontos."

var piada = fetch("https://v2.jokeapi.dev/joke/Any?type=single&lang=pt")
reply piada.joke

var target = args[0] ?? user

reply embed {
    title target.name
    description target.aboutMe ?? "Sem about me"
    color "#dc2626"
    thumbnail target.avatar
    field("Saldo", "{target.balance} iris", true)
    field("Bot?", "{target.isBot}", true)
}

var perfil = storage.get("nivel_{user.id}") ?? { xp: 0, nivel: 1 }

perfil.xp = perfil.xp + random(5, 15)

if perfil.xp >= perfil.nivel * 100 {
    perfil.nivel = perfil.nivel + 1
    perfil.xp = 0
    reply "Subiu para nível {perfil.nivel}!"
} else {
    reply "XP: {perfil.xp}/{perfil.nivel * 100}"
}

storage.set("nivel_{user.id}", perfil)